237 lines
8.4 KiB
Plaintext
237 lines
8.4 KiB
Plaintext
/* Default linker script, for normal executables */
|
|
OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm",
|
|
"elf32-littlearm")
|
|
OUTPUT_ARCH(arm)
|
|
ENTRY(_start)
|
|
/*SEARCH_DIR("/usr/arm-none-eabi/lib");*/
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
PROVIDE (__executable_start = SEGMENT_START("text-segment", 0x80008000)); . = SEGMENT_START("text-segment", 0x80008000);
|
|
/* .interp : { *(.interp) }
|
|
.note.gnu.build-id : { *(.note.gnu.build-id) }
|
|
.hash : { *(.hash) }
|
|
.gnu.hash : { *(.gnu.hash) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.gnu.version : { *(.gnu.version) }
|
|
.gnu.version_d : { *(.gnu.version_d) }
|
|
.gnu.version_r : { *(.gnu.version_r) }
|
|
.rel.init : { *(.rel.init) }
|
|
.rela.init : { *(.rela.init) }
|
|
.rel.text : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
|
|
.rela.text : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
|
|
.rel.fini : { *(.rel.fini) }
|
|
.rela.fini : { *(.rela.fini) }
|
|
.rel.rodata : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
|
|
.rela.rodata : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
|
|
.rel.data.rel.ro : { *(.rel.data.rel.ro .rel.data.rel.ro.* .rel.gnu.linkonce.d.rel.ro.*) }
|
|
.rela.data.rel.ro : { *(.rela.data.rel.ro .rela.data.rel.ro.* .rela.gnu.linkonce.d.rel.ro.*) }
|
|
.rel.data : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
|
|
.rela.data : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
|
|
.rel.tdata : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
|
|
.rela.tdata : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
|
|
.rel.tbss : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
|
|
.rela.tbss : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
|
|
.rel.ctors : { *(.rel.ctors) }
|
|
.rela.ctors : { *(.rela.ctors) }
|
|
.rel.dtors : { *(.rel.dtors) }
|
|
.rela.dtors : { *(.rela.dtors) }
|
|
.rel.got : { *(.rel.got) }
|
|
.rela.got : { *(.rela.got) }
|
|
.rel.bss : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
|
|
.rela.bss : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
|
|
.rel.iplt :
|
|
{
|
|
PROVIDE_HIDDEN (__rel_iplt_start = .);
|
|
*(.rel.iplt)
|
|
PROVIDE_HIDDEN (__rel_iplt_end = .);
|
|
}
|
|
.rela.iplt :
|
|
{
|
|
PROVIDE_HIDDEN (__rela_iplt_start = .);
|
|
*(.rela.iplt)
|
|
PROVIDE_HIDDEN (__rela_iplt_end = .);
|
|
}
|
|
.rel.plt :
|
|
{
|
|
*(.rel.plt)
|
|
}
|
|
.rela.plt :
|
|
{
|
|
*(.rela.plt)
|
|
}*/
|
|
.init :
|
|
{
|
|
KEEP (*(SORT_NONE(.init)))
|
|
}
|
|
.plt : { *(.plt) }
|
|
.iplt : { *(.iplt) }
|
|
.text :
|
|
{
|
|
*(.text.unlikely .text.*_unlikely)
|
|
*(.text.exit .text.exit.*)
|
|
*(.text.startup .text.startup.*)
|
|
*(.text.hot .text.hot.*)
|
|
*(.text .stub .text.* .gnu.linkonce.t.*)
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
*(.glue_7t) *(.glue_7) *(.vfp11_veneer) *(.v4_bx)
|
|
}
|
|
.fini :
|
|
{
|
|
KEEP (*(SORT_NONE(.fini)))
|
|
}
|
|
PROVIDE (__etext = .);
|
|
PROVIDE (_etext = .);
|
|
PROVIDE (etext = .);
|
|
.rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
|
|
.rodata1 : { *(.rodata1) }
|
|
.ARM.extab : { *(.ARM.extab* .gnu.linkonce.armextab.*) }
|
|
PROVIDE_HIDDEN (__exidx_start = .);
|
|
.ARM.exidx : { *(.ARM.exidx* .gnu.linkonce.armexidx.*) }
|
|
PROVIDE_HIDDEN (__exidx_end = .);
|
|
.eh_frame_hdr : { *(.eh_frame_hdr) }
|
|
.eh_frame : ONLY_IF_RO { KEEP (*(.eh_frame)) }
|
|
.gcc_except_table : ONLY_IF_RO { *(.gcc_except_table
|
|
.gcc_except_table.*) }
|
|
/* Adjust the address for the data segment. We want to adjust up to
|
|
the same address within the page on the next page up. */
|
|
. = ALIGN(CONSTANT (MAXPAGESIZE)) + (. & (CONSTANT (MAXPAGESIZE) - 1));
|
|
/* Exception handling */
|
|
.eh_frame : ONLY_IF_RW { KEEP (*(.eh_frame)) }
|
|
.gcc_except_table : ONLY_IF_RW { *(.gcc_except_table .gcc_except_table.*) }
|
|
.exception_ranges : ONLY_IF_RW { *(.exception_ranges .exception_ranges*) }
|
|
/* Thread Local Storage sections */
|
|
.tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
|
|
.tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
|
|
.preinit_array :
|
|
{
|
|
PROVIDE_HIDDEN (__preinit_array_start = .);
|
|
KEEP (*(.preinit_array))
|
|
PROVIDE_HIDDEN (__preinit_array_end = .);
|
|
}
|
|
.init_array :
|
|
{
|
|
PROVIDE_HIDDEN (__init_array_start = .);
|
|
KEEP (*(SORT(.init_array.*)))
|
|
KEEP (*(.init_array))
|
|
PROVIDE_HIDDEN (__init_array_end = .);
|
|
}
|
|
.fini_array :
|
|
{
|
|
PROVIDE_HIDDEN (__fini_array_start = .);
|
|
KEEP (*(SORT(.fini_array.*)))
|
|
KEEP (*(.fini_array))
|
|
PROVIDE_HIDDEN (__fini_array_end = .);
|
|
}
|
|
.ctors :
|
|
{
|
|
/* gcc uses crtbegin.o to find the start of
|
|
the constructors, so we make sure it is
|
|
first. Because this is a wildcard, it
|
|
doesn't matter if the user does not
|
|
actually link against crtbegin.o; the
|
|
linker won't look for a file to match a
|
|
wildcard. The wildcard also means that it
|
|
doesn't matter which directory crtbegin.o
|
|
is in. */
|
|
KEEP (*crtbegin.o(.ctors))
|
|
KEEP (*crtbegin?.o(.ctors))
|
|
/* We don't want to include the .ctor section from
|
|
the crtend.o file until after the sorted ctors.
|
|
The .ctor section from the crtend file contains the
|
|
end of ctors marker and it must be last */
|
|
KEEP (*(EXCLUDE_FILE (*crtend.o *crtend?.o ) .ctors))
|
|
KEEP (*(SORT(.ctors.*)))
|
|
KEEP (*(.ctors))
|
|
}
|
|
.dtors :
|
|
{
|
|
KEEP (*crtbegin.o(.dtors))
|
|
KEEP (*crtbegin?.o(.dtors))
|
|
KEEP (*(EXCLUDE_FILE (*crtend.o *crtend?.o ) .dtors))
|
|
KEEP (*(SORT(.dtors.*)))
|
|
KEEP (*(.dtors))
|
|
}
|
|
.jcr : { KEEP (*(.jcr)) }
|
|
.data.rel.ro : { *(.data.rel.ro.local* .gnu.linkonce.d.rel.ro.local.*) *(.data.rel.ro .data.rel.ro.* .gnu.linkonce.d.rel.ro.*) }
|
|
.dynamic : { *(.dynamic) }
|
|
.got : { *(.got.plt) *(.igot.plt) *(.got) *(.igot) }
|
|
.data :
|
|
{
|
|
__data_start = . ;
|
|
*(.data .data.* .gnu.linkonce.d.*)
|
|
SORT(CONSTRUCTORS)
|
|
}
|
|
.data1 : { *(.data1) }
|
|
_edata = .; PROVIDE (edata = .);
|
|
. = .;
|
|
__bss_start = .;
|
|
__bss_start__ = .;
|
|
.bss :
|
|
{
|
|
*(.dynbss)
|
|
*(.bss .bss.* .gnu.linkonce.b.*)
|
|
*(COMMON)
|
|
/* Align here to ensure that the .bss section occupies space up to
|
|
_end. Align after .bss to ensure correct alignment even if the
|
|
.bss section disappears because there are no input sections.
|
|
FIXME: Why do we need it? When there is no .bss section, we don't
|
|
pad the .data section. */
|
|
. = ALIGN(. != 0 ? 32 / 8 : 1);
|
|
}
|
|
_bss_end__ = . ; __bss_end__ = . ;
|
|
|
|
. = ALIGN(64);
|
|
. = . + 0x4000; /* 16KiB exception stack */
|
|
__stack_excp = .;
|
|
. = . + 0x4000; /* 16KiB interrupt stack */
|
|
__stack_int = .;
|
|
. = . + 0x4000; /* 16KiB syscall stack */
|
|
__stack_syscall = .;
|
|
. = . + 0x10000; /* 64KiB kernel startup stack */
|
|
__stack = .;
|
|
|
|
__end__ = . ;
|
|
_end = .; PROVIDE (end = .);
|
|
|
|
/* L1 page table must be aligned at 16KiB boundary */
|
|
. = ALIGN(16384);
|
|
_kernel_ptl1 = .;
|
|
. = . + 0x4000; /* Allocate 16KiB for L1 PT */
|
|
_kernel_ptl2 = .;
|
|
/* Calculate the number of L2 PTs to cover the kernel image + bss */
|
|
_kernel_numl2pt = ((_end - 0x80000000) / 1048576) + (((_end - 0x80000000) % 1048576)==0?0:1);
|
|
/* Allocate 1KiB for each L2 PT */
|
|
. = . + (0x400 * _kernel_numl2pt);
|
|
_kernel_pt_end = .;
|
|
/* If the page tables cross a L1 PT entry boundary (1MiB), signal to the
|
|
initialization code that an additional L1 entry and L2 page table must
|
|
be created for the memory containing the page tables */
|
|
_kernel_additional_pt = ((_kernel_pt_end & 0xfff00000) == (_kernel_ptl1 & 0xfff00000))?0:1;
|
|
_kernel_real_numl2pt = _kernel_numl2pt + _kernel_additional_pt;
|
|
. = . + (0x400 * _kernel_additional_pt);
|
|
_kernel_real_pt_end = .;
|
|
_kernel_numl2ent = ((_kernel_real_pt_end - 0x80000000) / 4096) + (((_kernel_real_pt_end - 0x80000000) % 4096)==0?0:1);
|
|
|
|
__heap_start = .; /* for _sbrk */
|
|
/* Virtual address space from end of kernel to 0xbfffffff is heap */
|
|
__heap_end = 0xc0000000;
|
|
|
|
/* Virtual address space for kernel scratchpad */
|
|
__scratch_start = 0xc0000000;
|
|
/* Map:
|
|
0xc0000000 - 0xc07fffff Kernel L2 pagetables
|
|
0xc0800000 - 0xc0ffffff Kernel pagecache
|
|
*/
|
|
__pc_start = 0xc0800000;
|
|
__pc_end = 0xc1000000;
|
|
__scratch_end = 0xe0000000;
|
|
/* Virtual address space for MMIO */
|
|
__io_start = 0xe0000000;
|
|
__io_end = 0xfffff000;
|
|
|
|
/DISCARD/ : { *(.note.GNU-stack) *(.gnu_debuglink) *(.gnu.lto_*) }
|
|
}
|